JSRUN 用代码说话

比较

编辑教程

比较

我们已经学习了条件语句,但如果我们不能进行比较,if语句并不怎么有用。 当然Vim允许我们比较值的大小,只是不会像看上去那么一目了然。

执行下面的命令:

:if 10 > 1
:    echom "foo"
:endif

显然,Vim会显示foo。现在执行下面的命令:

:if 10 > 2001
:    echom "bar"
:endif

Vim什么都不显示,因为10不比2001大。目前为止,一切正常。运行下面命令:

:if 10 == 11
:    echom "first"
:elseif 10 == 10
:    echom "second"
:endif

Vim显示second。没什么好惊讶的。让我们试试比较字符串。执行下面命令:

:if "foo" == "bar"
:    echom "one"
:elseif "foo" == "foo"
:    echom "two"
:endif

Vim输出two。还是没什么好惊讶的,所以我开头说的(译注:Vim的比较不像看上去那么直白)到底是指什么呢?

大小写敏感

执行下面的命令:

:set noignorecase
:if "foo" == "FOO"
:    echom "vim is case insensitive"
:elseif "foo" == "foo"
:    echom "vim is case sensitive"
:endif

Vim执行elseif分句,所以显然Vimscript是大小写敏感的。有道理,但没什么好震惊的。 现在执行下面命令:

:set ignorecase
:if "foo" == "FOO"
:    echom "no, it couldn't be"
:elseif "foo" == "foo"
:    echom "this must be the one"
:endif

啊! 就在这里停下来。是的,你所见属实。

==的行为取决于用户的设置。

我发誓我没忽悠你。你再试试看看。我没开玩笑,这不是我干的。

防御性编程

这意味着什么?意味着在为别人开发插件时,你不能信任==。 一个不加包装的==不能出现在你的插件代码里。

这个建议就像是"nmap VS nnoremap"一样。永远不要猜测你的用户的配置。 Vim既古老,又博大艰深。在写插件时,你不得不假定用户们的配置五花八门,千变万化。

所以怎样才能适应这荒谬的现实?好在Vim有额外两种比较操作符来处理这个问题。

执行下面的命令:

:set noignorecase
:if "foo" ==? "FOO"
:    echom "first"
:elseif "foo" ==? "foo"
:    echom "second"
:endif

Vim显示first因为==?是"无论你怎么设都大小写不敏感"比较操作符。现在执行下面的命令:

:set ignorecase
:if "foo" ==# "FOO"
:    echom "one"
:elseif "foo" ==# "foo"
:    echom "two"
:endif

Vim显示two因为==#是"无论你怎么设都大小写敏感"比较操作符。

故事的最后告诉我们一个道理:你应该总是用显式的大小写敏感或不敏感比较。 使用常规的形式是错的并且它终究会出错。打多一下就能拯救你自己于焦头烂额中。

当你比较整数时,这点小不同不会有什么影响。 不过,我还是建议每一次都使用大小写敏感的比较(即使不一定需要这么做),好过该用的时候忘记用了。

在比较整数时使用==#或==?都可以,而且将来一旦你改成字符串间的比较,它还会正确工作。

如果你真想用==比较整数也不是不行,不过要铭记,一旦被改成字符串间的比较,你需要修改比较操作符。

JSRUN闪电教程系统是国内最先开创的教程维护系统, 所有工程师都可以参与共同维护的闪电教程,让知识的积累变得统一完整、自成体系。 大家可以一起参与进共编,让零散的知识点帮助更多的人。
X
支付宝
9.99
无法付款,请点击这里
金额: 0
备注:
转账时请填写正确的金额和备注信息,到账由人工处理,可能需要较长时间
如有疑问请联系QQ:565830900
正在生成二维码, 此过程可能需要15秒钟